#!/bin/tcsh -f

switch (`uname -s``uname -r`)
case SunOS5*:
	breaksw
case Linux2*:
	breaksw
default:
	exec echo ${0}: does not run on `uname -s` `uname -r`
endsw

while($#argv)
	switch ("$1")
	case -d:
		set DEBUG
#		shift
#		breaksw
# fall through to verbose
	case -v:
		set VERBOSE
		shift
		breaksw
	case -c:
		set CHECK	# check if dir is in /tmp/superfind.<host> first
		shift
		breaksw
	default:
	    if (! $?TARGET) then
		set TARGET = `echo $1 | sed 's;/$;;'`
		shift
		breaksw
	    endif
	    if (! $?SUPERFIND && -f $1) then
		set SUPERFIND = $1
		shift
		breaksw
	    endif
		set DQ = '"'
		exec echo ${0}: "What do I do with $DQ$1$DQ?"
	endsw
end

set HOST = `hostname | sed 's;\.[Rr][Uu][Tt][Gg][Ee][Rr][Ss]\.[Ee][Dd][Uu];;'`


foreach DIR ( `/bin/ls -A $TARGET` )
    if ($?CHECK) then
	if (! $?SUPERFIND) then
	    set SUPERFIND = /tmp/superfind.$HOST
	    if (! -e $SUPERFIND) set SUPERFIND = Batch/Nightly/superfind.$HOST
	    if (! -e $SUPERFIND) exec echo /tmp/superfind.$HOST does not exist
	    set DATE = `date`
	    /bin/ls -l $SUPERFIND | grep " $DATE[2] *$DATE[3] " > /dev/null
	    if ($status) then
		echo $SUPERFIND is not from today:
		exec /bin/ls -l $SUPERFIND
	    endif
	endif
	grep $TARGET/$DIR $SUPERFIND > /dev/null
	if ($status) continue
    endif
    echo `date +%T` ./switch-gid -v 199 1234 $TARGET/$DIR
		    ./switch-gid -v 199 1234 $TARGET/$DIR
    echo `date +%T` ./switch-gid -v 199 1234 $TARGET/$DIR -l
		    ./switch-gid -v 199 1234 $TARGET/$DIR -l
    echo ""
end