#!/bin/csh -f

# preserve /var/mail/watrous for later testing of new screenmail.awk

# daw; 1/14/20

switch (`uname -s``uname -r`)
case SunOS5*:
    set DATE = /usr/local/gnu/bin/date
	breaksw
case Linux*:
    set DATE = /bin/date
	breaksw
default:
	exec echo ${0}: does not run on `uname -s` `uname -r`
endsw

set DEBUG

while($#argv)
	switch ("$1")
	case -d:
		set DEBUG = /bin/echo
#		shift
#		breaksw
# fall through to verbose
	case -v:
		set VERBOSE
		shift
		breaksw
	default:
		set DQ = '"'
		exec echo ${0}: "What do I do with $DQ$1$DQ?"
	endsw
end

set TMP = /tmp/`/usr/bin/basename $0`.$$

if (-e /tmp/watrous) then
    set FDATE = `/bin/ls -l /tmp/watrous | awk '{print $6,$7,$8}'`
    set TSTAMP = `$DATE --date="$FDATE" +%y%m%d`
    if (-e /tmp/watrous.$TSTAMP) set TSTAMP = `$DATE --date="$FDATE" +%y%m%d.%H%M`
    $DEBUG /bin/mv /tmp/watrous{,.$TSTAMP}
endif

$DEBUG /bin/cp -p /var/mail/watrous /tmp/watrous
$DEBUG /bin/chmod 400 /tmp/watrous

echo "awk -f ~/mailx-H.awk /tmp/watrous | awk -f screenmail.awkn DEBUG=1 | more"  > $TMP
echo "awk -f ~/mailx-H.awk /tmp/watrous | awk -f screenmail.awkn         | more" >> $TMP
source -h $TMP
echo ""
sed 's;.;  &;' $TMP
echo ""

/bin/rm -f $TMP